Public Class Form1
    'from http://msdn.microsoft.com/library/default.asp?url=/library/en-us/dnpag2/html/paght000007.asp
    'Generate Cryptographically Random Keys
    'To generate cryptographically random keys: 
    'Use the RNGCryptoServiceProvider class to generate a cryptographically strong random number. 
    'Choose an appropriate key size. The recommended key lengths are as follows: 
    ' For SHA1, set the validationKey to 64 bytes (128 hexadecimal characters). 
    ' For AES, set the decryptionKey to 32 bytes (64 hexadecimal characters). 
    ' For 3DES, set the decryptionKey to 24 bytes (48 hexadecimal characters).

Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
    CreateMachineKeyConfig()
End Sub

Private Sub CreateMachineKeyConfig()
    Dim sb As StringBuilder = New StringBuilder()
    sb.AppendLine("<machineKey ")
    sb.AppendLine(" validationKey = """ + GenRandomValues(128) + """")
    sb.AppendLine(" decryptionKey = """ + GenRandomValues(64) + """")
    sb.AppendLine(" validation = ""SHA1""")
    sb.AppendLine(" decryption = ""AES""")
    sb.AppendLine(" />")
    Me.TextBox1.Text = sb.ToString()
End Sub

Private Function GenRandomValues(ByVal len As Integer) As String
    Dim buff((len / 2) - 1) As Byte 'JBox added the decrement b/c of VB array decl syntax
    Dim rng As New RNGCryptoServiceProvider()
    rng.GetBytes(buff)
    Dim sb As New StringBuilder(Len)
    Dim i As Integer
    For i = 0 To buff.Length - 1
        sb.Append(String.Format("{0:X2}", buff(i)))
    Next i
    Return sb.ToString
End Function

Private Sub Button1_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button1.Click
    CreateMachineKeyConfig()
End Sub

End Class